🗺Полное решение Арт-практикума#7: Road Timeline Chart в Fine BI

Друзья, подходит к концу седьмой арт-практикум, и сегодня мы описываем решение нестандартного инструмента для визуализации этапов проектов, истории изменений или любых временных процессов. В путь!

1. Подготовка данных
Шаг 1. Выбираем опцию Formula Column
год

YEAR(${Order Date})

Шаг 2. Выбираем опцию Formula Column
индекс

DATEDIF(DATE(${год},1,1),${Order Date},"D")

Шаг 3. Выбираем опцию Formula Column
доп

SWITCH(${год},2017,0,2018,365,2019,730,2020,1095)

Шаг 4. Выбираем опцию Formula Column
new index

${индекс}+${доп}

2. Создание вычисляемых полей для графика
В настройках компонента создаем следующие калькуляции:
Segment Number

FLOOR(MAX(${Sample_superstore_index_new index})/180)

x

IF(MOD(${Sample_superstore_index_Segment Number},4) = 0,MAX(${Sample_superstore_index_new index})-(180*${Sample_superstore_index_Segment Number}),
MOD(${Sample_superstore_index_Segment Number},4) = 1, 180+SIN(RADIANS(MAX(${Sample_superstore_index_new index})-180))*30,
MOD(${Sample_superstore_index_Segment Number},4) = 2,((${Sample_superstore_index_Segment Number}+1)*180)-MAX(${Sample_superstore_index_new index}),
SIN(RADIANS(MAX(${Sample_superstore_index_new index})-180))*-30)

y

IF(MOD(${Sample_superstore_index_Segment Number},2) = 0,${Sample_superstore_index_Segment Number}*-1,
       (-1*${Sample_superstore_index_Segment Number}+COS(RADIANS(MAX(${Sample_superstore_index_new index})-180))))

радиус

SQRT(SUM_AGG(${Sample_superstore_index_Sales}))

3. Построение графика
🎾Выбираем тип графика Custom Chart → Point
🎾Настраиваем оси:
Горизонтальная ось (X): Поле x с агрегацией AVG
Вертикальная ось (Y): Поле y с агрегацией AVG
🎾Настраиваем отображение:
Color: Поле Order Date (формат "год")
Size: Поле радиус (размер 10-15)
Fine-grained: Поле Order Date (формат "год-месяц-день")
🎾Убираем лишние элементы:
Скрываем оси (Axes → Hide)
Убираем сетку (Grid Line → None)

Получается интерактивная временная шкала, где:
✅Каждая точка представляет событие
✅Размер точки зависит от показателя Sales
✅Цвет показывает год события
✅Расположение точек следует заданной логике

🏁 График готов! На какие данные примените?

#датаарт #артпрактикум #нетривиальные_графики #таймлайн